ansys体和壳耦合

请教各位高手一个问题，最近在做波形钢腹板建模，不知道顶底板和腹板怎么耦合啊，腹板用的壳单元，顶底板用的是实体单元。

用约束方程或者是用波形钢腹板的面去切割顶底板，然后执行Aovlap命令，都是可以实现的！

maldini_003 发表于 2013-1-19 16:32

                               
登录/注册后可看大图

用约束方程或者是用波形钢腹板的面去切割顶底板，然后执行Aovlap命令，都是可以实现的！

aovlap就可以耦合了吗？
我也在建模型，建好久了老是出错。尤其是腹板和顶板连接处应力特别混乱。
求高手指点一二。

FINISH
/CLEAR

/TITLE,ANALYSIS OF THE CORRUGATED STEEL WEBS

*SET,aw,0.43
*SET,bw,0.37
*SET,cw,0.22
*SET,THK,0.1
*SET,THK,0.1

/PREP7

ET,1,SHELL63
MP,EX,1,2.0E5  
MP,PRXY,1,0.3
MP,DENS,1,7800
R,1,THK,,,,,  
ET,2,SOLID65
MP,EX,2,3.5E10
MP,PRXY,2,0.1667
R,2,2,,,


K,1,0,0,0
K,2,0,0,30.03
LSTR,1,2

K,3,3.25,0,0
K,4,3.25,0.6,0
K,5,2.6,0.6,0
K,6,2.3,0.3,0
K,7,-2.3,0.3,0
K,8,-2.6,0.6,0
K,9,-3.25,0.6,0
K,10,-3.25,0,0
A,3,4,5,6,7,8,9,10


K,11,0.75,4.2,0
K,12,2.6,3.9,0
K,13,3.25,3.9,0
K,14,6,4.3,0
K,15,6,4.5,0
K,16,-6,4.5,0
K,17,-6,4.3,0
K,18,-3.25,3.9,0
K,19,-2.6,3.9,0
K,20,-0.75,4.2,0
A,11,12,13,14,15,16,17,18,19,20

APLOT,ALL



VDRAG,ALL,,,,,,1,,,,,

LDELE,1,,,1
ALLSEL,ALL
NUMCMP,ALL

VPLOT,ALL

*GET,FIRST_KNUM,KP,0,NUM,MAX

*DO,I,1,19,1
K,FIRST_KNUM+1+4*(I-1),2.815,0,1.6*(I-1)
K,FIRST_KNUM+2+4*(I-1),2.815,0,aw+1.6*(I-1)
K,FIRST_KNUM+3+4*(I-1),3.035,0,aw+bw+1.6*(I-1)
K,FIRST_KNUM+4+4*(I-1),3.035,0,2*aw+bw+1.6*(I-1)
*ENDDO

*GET,SECOND_KNUM,KP,0,NUM,MAX

*DO,I,SECOND_KNUM-75,SECOND_KNUM-1,1
LSTR,I,I+1
*ENDDO


K,SECOND_KNUM+1,2.815,4.5,0

LSTR,SECOND_KNUM-75,SECOND_KNUM+1

*GET,FIRST_LNUM,LINE,0,NUM,MAX

LSEL,S,LOC,Y,0,,,
LSEL,R,LOC,X,2.815,3.035,,
ADRAG,ALL,,,,,,FIRST_LNUM,,,,,

LDELE,FIRST_LNUM,,,1
ALLSEL,ALL
NUMCMP,ALL

ASEL,S,LOC,Y,0,4.5,,
ASEL,R,LOC,X,2.815,3.035,,
ASEL,U,LOC,Y,0.6,,,
ASEL,U,LOC,Y,3.9,,,
AGLUE,ALL
CM,WEB_L_FIRST,AREA
CMSEL,S,WEB_L_FIRST,AREA


ARSYM,X,ALL,,,,,,
ASEL,S,LOC,Y,0,4.5,,
ASEL,R,LOC,X,-2.815,-3.035,,
ASEL,U,LOC,Y,0.6,,,
ASEL,U,LOC,Y,3.9,,,
CM,WEB_R_FIRST,AREA

ALLSEL,ALL

WPOFFS,0,0.3,0
WPROTA,0,90,0
VSBW,1,0,0

WPOFFS,0,0,-3.9
VSBW,2,0,0

WPCSYS,-1
VSBA,ALL,ALL,,,KEEP
AOVLAP,ALL
NUMMRG,KP

ASEL,S,LOC,Y,0.3,4.2,,
ASEL,R,LOC,X,2.815,3.035,,
ASEL,U,LOC,Y,0.6,,,
ASEL,U,LOC,Y,3.9,,,
AGLUE,ALL
CM,WEB_L_FIRST,AREA
CMSEL,S,WEB_L_FIRST,AREA


ASEL,S,LOC,Y,0.3,4.2,,
ASEL,R,LOC,X,-2.815,-3.035,,
ASEL,U,LOC,Y,0.6,,,
ASEL,U,LOC,Y,3.9,,,
AGLUE,ALL
CM,WEB_R_FIRST,AREA
                       
CMSEL,ALL
AATT,1,1,1,0
AESIZE,ALL,0.2
AMESH,ALL

ALLSEL
VSEL,ALL
VPLOT
VATT,2,2,2,0
ESIZE,0.4,0
MSHKEY,0
MSHAPE,1,3D
VMESH,ALL


NUMMRG,ALL  
NUMCMP,ALL  


/SOLU
ANTYPE,STATIC

LSEL,S,LOC,Y,0,,,
LSEL,R,LOC,Z,0,,,
NSLL,S,ALL
D,ALL,UX
D,ALL,UY
D,ALL,UZ
D,ALL,ROTY
D,ALL,ROTZ

LSEL,S,LOC,Y,0,,,
LSEL,R,LOC,Z,30.03,,,
NSLL,S,ALL
D,ALL,UX
D,ALL,UY
D,ALL,ROTY
D,ALL,ROTZ

ALLSEL
ACEL,,9.8

NSEL,S,LOC,Y,4.5,,,
NSEL,R,LOC,Z,15,15.3,
NSEL,R,LOC,X,-3.5,3.5,
*GET,NUMD,NODE,,COUNT
F,ALL,FY,-5.074787195/NUMD
ALLSEL
SOLVE

WPCSYS,-1
VSBA,ALL,ALL,,,KEEP
AOVLAP,ALL
NUMMRG,KP

重点看这几句命令流吧  做的一个小梁的模型 也就是练手的

maldini_003 发表于 2013-2-1 18:08

                               
登录/注册后可看大图

WPCSYS,-1
VSBA,ALL,ALL,,,KEEP
AOVLAP,ALL

十分感谢前辈的回复和帮助！！
我将那段命令流仔细看了，第一次运行发现加载后腹板被压扁了。我就改了一下材料属性：
ET,1,SHELL63
MP,EX,1,2.05E+5  
MP,PRXY,1,0.3
MP,DENS,1,7850E-9                   !改动处，原为MP,DENS,1,7800
MP,ALPX,1,1.2E-5                       !添加处
R,1,THK,,,,,
ET,2,SOLID65
MP,EX,2,3.32E+4                       !改动处，原为MP,EX,2,3.5E10
MP,PRXY,2,0.2                           !改动处，原为MP,PRXY,2,0.1667
MP,DENS,2,2550E-9                  !添加处
MP,ALPX,2,1.0E-05                    !添加处
MP,REFT,2,20                             !添加处
R,2,2,,,

这样的话结果好像会好一点。
我有几个问题想请教一下前辈：
1、第一个也是最重要的：为什么用aovlap就可以实现不同单元的耦合了？这种方法只能用于面与体的耦合吗？
2、为什么对支座处约束了ROTY和ROTZ？
3、前辈加荷载的方式是对节点用f命令。但如果选中的节点疏密不一样的话，岂不是不能当做均布荷载了？
4、例子中的腹板插至顶板表面和底板底面，如果让腹板插到顶底板中1/2位置会不会更好呢？

谢谢！

yoohooyoohoo 发表于 2013-2-3 02:17

                               
登录/注册后可看大图

十分感谢前辈的回复和帮助！！
我将那段命令流仔细看了，第一次运行发现加载后腹板被压扁了。我就改了一 ...

这个力是我随便加的，后处理的结果没有什么实用价值，当时也是为了处理怎么共节点的问题，其实这种方法，对于这种等高的箱梁，还是比较使用，而且也可以处理一下，把混凝土顶底板划分成漂亮的六面体网格，但是相对来说要多操作几步，对于变高的箱梁，我师兄的毕业论文做的是波形钢腹板的矮塔斜拉桥的局部分析，他用的是约束方程也就是CPINTF命令，也就是说的波形钢腹板可以与混凝土单独各自分网，最后钢板和混凝土的单元直接的耦合采用这种界面约束方程来处理，也是可以的，仅供参考，说的不对的地方，大家指正！

yoohooyoohoo 发表于 2013-2-3 02:17

                               
登录/注册后可看大图

十分感谢前辈的回复和帮助！！
我将那段命令流仔细看了，第一次运行发现加载后腹板被压扁了。我就改了一 ...

4、例子中的腹板插至顶板表面和底板底面，如果让腹板插到顶底板中1/2位置会不会更好呢？
钢板如果不完全伸入顶底板，你用VSBA命令，体（顶底板）是不能被切开的，不信你可以试一试，把体切开的目的也主要是为了在钢板和顶底板的交界面上进行下一步AOVLAP的操作，形成共节点的目的！

yoohooyoohoo 发表于 2013-2-3 02:17

                               
登录/注册后可看大图

十分感谢前辈的回复和帮助！！
我将那段命令流仔细看了，第一次运行发现加载后腹板被压扁了。我就改了一 ...

为什么对支座处约束了ROTY和ROTZ？
当时我用civil建立了一个杆系模型，想做对比分析，这个位置我个人认为如果想和civil里面的力吻合的较好的话，应该再梁端截面形心建立一个主节点，然后采用CERIG命令，形成刚性域，然后再给主节点施加和civil杆系模型中相同的边界条件，该模型的约束也是和实际模型有点儿出入的，不具有工程实际意义，当时建立该模型的主要目的也是为了试验如何处理波形钢腹板和混凝土之间节点的耦合，我这个命令流主要是采用了共节点的方法，你可以试试采用约束方程的方法，网上很多关于波形钢腹板的学术论文都会讲这个问题。

yoohooyoohoo 发表于 2013-2-3 02:17

                               
登录/注册后可看大图

十分感谢前辈的回复和帮助！！
我将那段命令流仔细看了，第一次运行发现加载后腹板被压扁了。我就改了一 ...

你可以多切分几道顶板和底板，可以划分出很漂亮的六面体网格来

maldini_003 发表于 2013-2-3 10:55

                               
登录/注册后可看大图

你可以多切分几道顶板和底板，可以划分出很漂亮的六面体网格来

感谢回复！

我之前尝试过采用接触单元的MPC方法，因为想看看剪力滞效应，先简化模型建了直的腹板来看看结果，但效果还是很不理想，腹板位置正应力非常奇怪（见下图已）。

在改了很多次模型后，我猜测可能是我的网格划得不好。

因为是新手，所以想请问前辈：顶底板里有波纹状的线，应该如何扫略网格？

谢谢！！

yoohooyoohoo 发表于 2013-2-4 02:49

                               
登录/注册后可看大图

感谢回复！

我之前尝试过采用接触单元的MPC方法，因为想看看剪力滞效应，先简化模型建了直的腹板来看看 ...

你的剪力滞路径云图有些异常，你的模型中如果顶板带有单向横坡的话，应力云图可能回是这个样子，如果顶板没有单向横坡，腹板交界处顶板的纵桥向正应力应该是对称的

maldini_003 发表于 2013-2-4 11:08

                               
登录/注册后可看大图

你的剪力滞路径云图有些异常，你的模型中如果顶板带有单向横坡的话，应力云图可能回是这个样子，如果顶板 ...

不好意思，这两天电脑出点问题上不了网没来得及回复。

我的模型里顶板没有横坡，但腹板交界处顶板的纵桥向正应力有点混乱和不对称，这个问题已经弄了挺久了还是没解决。
我现在猜测是因为模型在网格方式不相同的地方数据不好。想换个思路划分网格。

另外，我注意到前辈用路径的方式输出结果。
我现在查看应力的方式是：把横截面节点的坐标和正应力值存进数组，对坐标排序后输出应力值生成TXT文件。感觉有点绕。
!preparation
*get,nomin,node,,num,min                 !得出所选节点中最小节点号：nomin
*get,nnode,node,,count                          !得到节点数：nnode

*dim,num,array,nnode,3                         !定义了一个名为num的数值型数组，大小为"nnode"行3列，分别存放节点no和z坐标
num(1,1)=nomin                                       
num(1,2)=nz(nomin)

!assign values to the array
*do,i,2,nnode                                          !从 i=2 运行到 i=nnode （共nnode-1次）
num(i,1)=ndnext(num(i-1,1))                !ndnext(N):下一个比N的编号大的函数
num(i,2)=nz(num(i,1))
*enddo

!sort by location
k=nnode-1
*do,i,1,k
*do,j,1,nnode-i
*if,num(j,2),gt,num(j+1,2),then        !如果num(j,2)大于num(j+1,2)，就执行：

nt=num(j,2)                                        !两者的z值对调
num(j,2)=num(j+1,2)                       
num(j+1,2)=nt

nt=num(j,1)                                        !两者的node序号对调
num(j,1)=num(j+1,1)
num(j+1,1)=nt
*endif
*enddo
*enddo

*do,i,1,nnode                                        !给第三列赋值sx
*get,nsx,node,num(i,1),s,x                                       
num(i,3)=nsx
*enddo


前辈处理网格和结果的方式我之前没想到过。
可以请教一下扫略映射和剪力滞输出的命令流讨论学习吗？

谢谢关注！

maldini_003 发表于 2013-2-4 11:08

                               
登录/注册后可看大图

你的剪力滞路径云图有些异常，你的模型中如果顶板带有单向横坡的话，应力云图可能回是这个样子，如果顶板 ...

新年快乐！

刚刚试了一下用扫掠来网格划分，但是在腹板与顶底板交界处，“腹板的划分”跟“顶板的划分”无论先划分哪一个，另一个就划分不了，不知道是不是因为共面的原因。

网格完腹板后，在网格顶底板的时候，就出现下面这个error。

                               
登录/注册后可看大图

还是跑来求教网格划分和剪力滞路径的命令流。

望前辈不吝指教。谢谢！

maldini_003 发表于 2013-2-4 11:08

                               
登录/注册后可看大图

你的剪力滞路径云图有些异常，你的模型中如果顶板带有单向横坡的话，应力云图可能回是这个样子，如果顶板 ...

前辈好~
刚刚试了一下换用shell63，就可以划分了。我本来用的shell281就不行，怎么会这样的？
不知道换了单元影响大不大呢？
谢谢！

======================================
刚刚试了一下，solve到时没问题了，但是，剪力滞有点问题。下图是跨中截面的应力图。