Angel 发表于 2009-10-15 12:53:15

重奖征集国内悬索桥结构分析（计算或者咨询）报告

本帖最后由 Angel 于 2009-10-15 12:54 编辑

国内悬索桥结构分析（计算或者咨询）报告，自锚悬索桥的更好
要求：
   1.注明分析所采用的软件或者工具的详细信息
   2.注明相应模型的桥名和位置。

bmwwmbibm 发表于 2010-3-23 17:08:23

(1)介绍了自锚式悬索桥的发展历史和国内外的应用现状,总结了自锚式悬索桥的基本构造特点和受力特征,指出了自锚式悬索桥存在问题和发展趋势; (2)全面介绍三汊矶大桥的设计、计算、施工;指出了自锚式悬索桥中存在的主要问题; (3)提出了自锚式悬索桥主缆锚固系统设计的基本原则,总结了自锚式悬索桥采用混凝土加劲梁、钢混组合加劲梁和钢加劲梁时的主缆锚固系统,归纳得出主缆锚固可采取直接锚固、混凝土结构中散开锚固、钢结构中散开锚固和环绕式锚固等不同方式;对各种锚固方式的优缺点和适用范围进行了合理评价。这对今后同类桥型的设计和施工有重要的指导作用。 (4)对三汊矶自锚式悬索桥锚固结构进行了1:3.2大比例模型试验。

bmwwmbibm 发表于 2010-3-23 17:12:52

回复 2# bmwwmbibm

补上前面的两个压缩分卷

(4)对三汊矶自锚式悬索桥锚固结构进行了1:3.2大比例模型试验。

kaixin 发表于 2010-4-20 17:49:09

网上搜集的几个吊桥小资料，感觉还有点用

kaixin 发表于 2010-4-20 17:52:40

网上搜集的几个吊桥小资料，感觉还有点用

wangji790512 发表于 2011-1-24 14:24:17

一座跨径240m的钢桁架悬索桥（南盘江大桥）的加固方案设计文件，包含整套计算说明及加固说明，希望符合楼主的预期。
使用软件为MIDAS.

hjh507 发表于 2011-1-24 15:51:33

下载看了一下，楼上的资料5个堡币实在是有点贵了，感觉不值，如果说把计算模型放上去还差不多。

jwjjwjjwj 发表于 2011-1-27 16:47:48

南京长江第四大桥
三跨吊悬索桥总体分析报告
（主跨1418 米）


主缆三跨布置为583＋1418＋474＝2475m；主梁跨径布置为417＋1418＋357＝2192m；北边跨吊杆布置为11+26×15+16=417m，中跨吊杆布置为16＋31×15＋30×15.2＋31×15＋16＝1418m，南边跨吊杆布置为16＋22×15＋11＝357m。主缆矢跨比1/9，矢高157.5m。计算程序采用 ANSYS。




中交公路规划设计院有限公司
二OO 六年十二月


samany170206 发表于 2011-2-15 22:25:39

某自锚式悬索桥计算报告，很给力！

wangji790512 发表于 2011-2-17 11:56:21

回复 hjh507 的帖子

堡币多少随手打出来的，我再放个ANSYS命令流，希望有用，也是上边那个桥的
/PREP7
ET,1,BEAM4   !加劲桁架，纵向分配梁，横梁，桥塔         
et,2,link10!缆索，吊索   
et,3,shell63 !桥面板单元
keyopt,2,3,0!只受拉不受压
!材料                        
!1 主缆、吊索、斜索                     
MP,EX,1,2.0e11            
MP,PRXY,1,0.167               
mp,dens,1,7850      
!2 桁架                              
MP,EX,2,2.0e11                  
MP,PRXY,2,0.167
mp,dens,2,7850               
!3 主塔，桥面板
MP,EX,3,3.3e10                  
MP,PRXY,3,0.2   
mp,dens,3,2600               
!定义实常数
R,1,19.6*91*19/1000000,0.00338         !主缆
R,2,38.5*61/1000000,0               !吊索
!纵向加劲桁架
R,3,0.01712,0.482e-3,0.165e-3,0.38,0.38    !加劲梁上、下弦杆
R,4,0.01045,0.279e-3,0.369e-4,0.24,0.378   !加劲梁斜腹杆、竖杆
R,5,0.0037,0.917e-5,0.917e-5,0.16,0.16   !上风构、下风构、纵向分配梁
!横向加劲桁架实常数
R,6,0.004454*2,0.385e-4,0.113e-5,0.182,0.25               !上下弦杆
R,7,0.008352,0.264e-4,0.468e-4,0.36,0.18                  !外侧斜杆
R,8,0.007392,0.183e-4,0.329e-4,0.32,0.16                  !内侧斜杆、竖杆
R,9,3.8*5.8,3.8*5.8**3/12,3.8**3*5.8/12,3.8,5.8             !桥塔实常数
R,10,2.8*4.8,2.8*4.8**3/12,2.8**3*4.8/12,2.8,4.8            !塔柱实常数
R,11,5.8*4.25,5.8*4.25**3/12,5.8**3*4.25/12,5.8,4.25      !桥塔横梁1实常数
R,12,4.8*1.58,4.8*1.58**3/12,4.8**3*1.58/12,4.8,1.58      !桥塔横梁2实常数
R,13,0.3                                                    !桥面板人行道板及车行道板实常数               
!中跨主缆
q1=259
H=23545.9
b=H/q1*3.343
a=240/(2*b)
k=(exp(a)+exp(-a))/2
*do,i,1,81
xi=3*(i-1)
yi=-b*(k-(exp(1/b*xi-a)+exp(-1/b*xi+a))/2)+25.58
n,i,xi,yi,-6
n,i+100,xi,yi,6
*enddo
!背索
n,82,-92.45,-4.172,-6
n,182,-92.45,-4.172,6
n,83,332.45,-4.172,-6
n,183,332.45,-4.172,6
!加劲梁节点
*do,i,2,80
*do,j,1,7                                                                        
n,i+100*(j+1),3*(i-1),0,(j-1)*2-6                                                      
*enddo
*enddo
*do,i,2,80
*do,j,8,14                                                                        
n,i+100*(j+1),3*(i-1),-2.7,(j-8)*2-6                                                      
*enddo
*enddo

!塔节点
n,1601,0,-40,-6
n,1701,0,-40,6
n,1801,240,-40,-6
n,1901,240,-40,6
*do,i,1,20
n,i+1601,0,-40+2*i,-6
n,i+1701,0,-40+2*i,6
n,i+1801,240,-40+2*i,-6
n,i+1901,240,-40+2*i,6
*enddo
!柱节点
*do,i,1,12
n,i+1621,0,2*i,-6
n,i+1721,0,2*i,6
n,i+1821,240,2*i,-6
n,i+1921,240,2*i,6
*enddo
n,1634,0,25.58,-6
n,1734,0,25.58,6
n,1834,240,25.58,-6
n,1934,240,25.58,6
!生成主缆
type,2
mat,1
real,1
*do,i,1,80
e,i,i+1
e,100+i,101+i
*enddo
e,1,82
e,81,83
e,101,182
e,181,183
!生吊杆单元
type,2
mat,1
real,2
*do,i,1,39
e,2*i+1,200+2*i+1
e,100+2*i+1,800+2*i+1
*enddo
         
!生成加劲梁上下弦杆
type,1
mat,2
real,3
*do,i,2,79
e,i+200,i+201
e,i+800,i+801
*enddo
*do,i,2,79
e,i+900,i+901
e,i+1500,i+1501
*enddo
!生加劲梁斜腹杆、竖杆
type,1
mat,2
real,4
*do,i,1,39
e,2*i+200,2*i+901
e,2*i+800,2*i+1501
e,2*i+901,2*i+202
e,2*i+1501,2*i+802
*enddo
*do,i,1,79
e,i+201,i+901
e,i+801,i+1501
*enddo
!上风构
type,1
mat,2
real,5
e,202,503
e,802,503
e,280,579
e,880,579
*do,i,1,19
e,2*i+201,2*i+503
e,2*i+801,2*i+503
*enddo
*do,i,1,19
e,281-2*i,579-2*i
e,881-2*i,579-2*i
*enddo
!下风构
e,1102,903
e,1302,1503
*do,i,1,19
e,2*i+1101,2*i+903
e,2*i+1301,2*i+1503
*enddo
*do,i,1,19
e,1181-2*i,979-2*i
e,1381-2*i,1579-2*i
*enddo

!纵向分配梁
*do,i,1,78
e,i+1101,i+1102
e,i+1301,i+1302
*enddo
!横向加劲桁架上下弦杆
type,1
mat,2
real,6
*do,i,1,6
e,2+100*(i+1),2+100*(i+2)
e,2+100*(i+8),2+100*(i+9)
e,80+100*(i+1),80+100*(i+2)
e,80+100*(i+8),80+100*(i+9)
*enddo
*do,i,1,39
*do,j,1,6
e,2*i+100*(j+1)+1,2*i+100*(j+2)+1
e,2*i+100*(j+8)+1,2*i+100*(j+9)+1
*enddo
*enddo
!横向加劲桁架外侧斜杆
type,1
mat,2
real,7
e,902,302
e,1502,702
e,980,380
e,1580,780
*do,i,1,39
e,2*i+900+1,2*i+300+1
e,2*i+1500+1,2*i+700+1
*enddo
!横向加劲桁架内侧斜杆、竖杆
type,1
mat,2
real,8
e,302,1102
e,1102,502
e,502,1302
e,1302,702
e,402,1102
e,602,1302
e,380,1180
e,1180,580
e,580,1380
e,1380,780
e,480,1180
e,680,1380
*do,i,1,39
e,2*i+300+1,2*i+1100+1
e,2*i+1100+1,2*i+500+1
e,2*i+500+1,2*i+1300+1
e,2*i+1300+1,2*i+700+1
e,2*i+400+1,2*i+1100+1
e,2*i+600+1,2*i+1300+1
*enddo
!生成桥塔
type,1
mat,3
real,9
*do,i,1,20
e,i+1600,i+1601
e,i+1700,i+1701
e,i+1800,i+1801
e,i+1900,i+1901
*enddo
!生成塔柱
type,1
mat,3
real,10
*do,i,1,13
e,i+1620,i+1621
e,i+1720,i+1721
e,i+1820,i+1821
e,i+1920,i+1921
*enddo
!生成横梁1
type,1
mat,3
real,11
e,1620,1720
e,1820,1920
!生成横梁2
type,1
mat,3
real,12
e,1632,1732
e,1832,1932
!生成桥面板
type,3
mat,3
real,13
*do,i,2,80
*do,j,19,25                                                                        
n,i+100*(j+1),3*(i-1),0,(j-19)*2-6                                                      
*enddo
*enddo
*do,i,2,79
*do,j,19,24
e,i+100*(j+1),i+100*(j+1)+1,i+100*(j+2)+1,i+100*(j+2)
*enddo
*enddo
*do,i,2,80
cp,next,ux,i+200,i+2000
cp,next,uy,i+200,i+2000
cp,next,uz,i+200,i+2000
cp,next,ux,i+800,i+2600
cp,next,uy,i+800,i+2600
cp,next,uz,i+800,i+2600
*enddo

*do,i,1,39
*do,j,2,6
cp,next,ux,2*i+100*(j+1)+1,2*i+100*(j+19)+1
cp,next,uy,2*i+100*(j+1)+1,2*i+100*(j+19)+1
cp,next,uz,2*i+100*(j+1)+1,2*i+100*(j+19)+1
*enddo
*enddo
*do,j,2,6
cp,next,ux,2+100*(j+1),2+100*(j+19)
cp,next,uy,2+100*(j+1),2+100*(j+19)
cp,next,uz,2+100*(j+1),2+100*(j+19)
cp,next,ux,80+100*(j+1),80+100*(j+19)
cp,next,uy,80+100*(j+1),80+100*(j+19)
cp,next,uz,80+100*(j+1),80+100*(j+19)
*enddo
esel,s,type,,3
sfe,all,1,pres,,1250+1369,1250+1369,1250+1369,1250+1369
allsel
!!!!塔顶索鞍与塔耦合
cp,next,ux,1,1634   
cp,next,uy,1,1634                              
cp,next,uz,1,1634
cp,next,ux,101,1734      
cp,next,uy,101,1734                              
cp,next,uz,101,1734
cp,next,ux,81,1834
cp,next,uy,81,1834                           
cp,next,uz,81,1834
cp,next,ux,181,1934   
cp,next,uy,181,1934                              
cp,next,uz,181,1934
allsel

/solu
*do,i,1,7
D,902+100*(i-1),ux            
D,902+100*(i-1),uy
D,902+100*(i-1),uz
D,980+100*(i-1),ux         
D,980+100*(i-1),uy
D,980+100*(i-1),uz
*ENDDO
D,1601,ALL
D,1701,ALL
D,1801,ALL
D,1901,ALL
D,82,UX
D,82,UY
D,82,UZ
D,182,UX
D,182,UY
D,182,UZ
D,83,UX
D,83,UY
D,83,UZ
D,183,UX
D,183,UY
D,183,UZ
allsel
nsel,s,node,,2202,2280,1
f,all,fy,-10500*240/79
allsel
nsel,s,node,,2402,2480,1
f,all,fy,-10500*240/79
allsel
f,2241,fy,-360000
f,2441,fy,-360000
allsel

/SOLU
ANTYPE,0                                             !首先进行静力分析，得到预应力
ACEL,,9.8                                                !考虑重力影响
TIME,1                                                    !设置求解时间
NSUB,10,20,5                                    !设置载荷子步为10
OUTRES,ALL,ALL                                 !输出每一步的所有结果
NLGEOM,ON                                    !打开大变形效应
SSTIF,ON                                                !激活应力刚化效应
ALLS                                                       !选中所有的元素
SOLVE                                                   !求解
allsel

lokisu2k8 发表于 2011-2-24 23:49:07

希望悬索桥的高手们能多多分享啊

littor 发表于 2011-3-9 13:56:41

感觉是个好东西。目前正要设计跨径160m左右的自锚式悬索桥
页: [1]
查看完整版本: 重奖征集国内悬索桥结构分析（计算或者咨询）报告